geuni

/*
* Eases color changes
* Created by Justin Wilaby
* @param oc - original color or starting point
* @param nc - new color to ease to
* @param m - movieclip to ease color on
* usage: new EaseColor(originalColor, newColor, movieClip, completionTime, easeEquation);
ease = new EaseColor(0xff0000, 0x3399ff, myMc, 75, mx.transitions.easing.Bounce.easeOut);
*/
import flash.geom. *;
class EaseColor
{
/*
* color objects
*/
private var colorTrans : ColorTransform;
private var trans : Transform;
// ----------------------------------
private var m:MovieClip;
/*
* init
*/
public function EaseColor (oc : Number, nc : Number, movieclip : MovieClip, completionTime:Number, easeEquation:Function)
{
//trace("oc : "+oc +" nc : "+nc)
m = movieclip;
//decimal value for original color
var origRgb = oc;
//extacts the red channel
var origRed = (origRgb & 16711680) >> 16;
//extacts the green channel
var origGreen = (origRgb & 65280) >> 8;
//extacts the blue channel
var origBlue = origRgb & 255;
// --------------------------------
//decimal value for new color
var newRgb = nc;
//extacts the red channel
var newRed = (newRgb & 16711680) >> 16;
//extacts the green channel
var newGreen = (newRgb & 65280) >> 8;
//extacts the blue channel
var newBlue = newRgb & 255;
//---------------------------------
var O = this;
var time : Number = 0;
/*
*easeing engine
* usage: easeEquation (timeCount, start, finish - start, easeTime);
*/
var doEase = function (Void) : Void
{
  var tRed = easeEquation (time, origRed, newRed - origRed, completionTime);
  var tGreen = easeEquation (time, origGreen, newGreen - origGreen, completionTime);
  var tBlue = easeEquation (time, origBlue, newBlue - origBlue, completionTime);
  //trace("tRed : "+tRed+" tGreen : "+tGreen+"tBlue : "+tBlue)
  //Convert back to Hex
  var c = tRed << 16 | tGreen << 8 | tBlue;
  c = c >= 0xFFFFFF ? 0xFFFFFF : c;
  //trace(c)
  if (time >= completionTime)
  {
   clearInterval (intv);
  }
  updateAfterEvent ();
  time ++;
  O.changeColor (c);
};
var intv = setInterval (doEase, 10);
}
/*
* Changes color of a movieclip
* @param m - target movieclip
* @param newColor - the new color of the movieclip
*/
private function changeColor (newColor : Number) : Void
{
//trace("changeColor ( newColor  : "+newColor +")")
colorTrans = new ColorTransform ();
colorTrans.rgb = newColor;
trans = new Transform (m);
//trace("m : "+m)
trans.colorTransform = colorTrans;
//trace(trans.colorTransform)
  }
}